changer l'extension pour une collection de fichier

[Sebwan]

Bonjour à tous,

J'ai un programme qui me sort tout des fichiers .txt et j'aimerais les transformer en fichier .xls .

Pour ce faire, j'aimerais utiliser les formules de type file collection(voir ci-dessous), et récupérer toute la liste des mes fichiers txt, puis d'extraire de f1.name le nom du fichier (sans l'extension) afin de le sauvegarder en.xls .

1°) Est-ce possible?

2°) Si oui, comment?

Merci d'avance

Dim fs, f, f1, fc, s
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFolder(specdossier)
    Set fc = f.Files
    For Each f1 in fc
        s = s & f1.name 
        s = s & vbCrLf
    Next
    MsgBox s

 

[tototiti2008]

Re : changer l'extension pour une collection de fichier

Bonjour Sebwan,

il s'agit de les renommer ou de les convertir ?

 

[Sebwan]

Re : changer l'extension pour une collection de fichier

Si il y a en plus moyen de les convertir, ce serait genial, mais même juste les renommer, ce serait déjà bien!

Merci

 

[tototiti2008]

Re : changer l'extension pour une collection de fichier

Re,

pour les renommer :

Sub test()
Dim fs, f, f1, fc, s
specdossier = "C:\DossierAA"
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFolder(specdossier)
    Set fc = f.Files
    For Each f1 In fc
        If UCase(f1.Name) Like "*.TXT" Then
            Name specdossier & "\" & f1.Name As specdossier & "\" & Left(f1.Name, Len(f1.Name) - 4) & ".xls"
        End If
    Next
End Sub

pour les convertir, à part les ouvrir avec un OpenText et les enregistrer sous, je ne vois pas...

 

[Sebwan]

Re : changer l'extension pour une collection de fichier

Parfait! Un grand merci!

Je fonce essayer ça tout de suite!

 

[Staple1600]

Re : changer l'extension pour une collection de fichier

Bonsoir

Renommer des txt en xls n'est pas convertir des txt en xls

Comme le dit tototiti2008 , voir de ce coté

pour les convertir, à part les ouvrir avec un OpenText et les enregistrer sous

 

[Staple1600]

Re : changer l'extension pour une collection de fichier

Re

EDITION:

Une version modifiée plus lisible

Sub import_ii()
Dim fs
Set fs = Application.FileSearch
Application.ScreenUpdating = False
    With fs
    .LookIn = "C:\temp"
    .Filename = "*.txt"
        If .Execute > 0 Then
        For i = 1 To .FoundFiles.Count
        Workbooks.OpenText .FoundFiles(i), xlWindows, 1, _
        xlDelimited, xlDoubleQuote, True, False, True
        ActiveWorkbook.SaveAs Left(.FoundFiles(i), _
        Len(.FoundFiles(i)) - 4), FileFormat:=xlNormal
        ActiveWorkbook.Close SaveChanges:=True
        Next i
        End If
    End With
Application.ScreenUpdating = True
End Sub

Un exemple simple

Ici le séparateur est le ;

Sub import()
Dim fs
Set fs = Application.FileSearch
With fs
.LookIn = "C:\temp"
.Filename = "*.txt"
If .Execute > 0 Then
For i = 1 To .FoundFiles.Count
Workbooks.OpenText Filename:=.FoundFiles(i) _
, Origin:=xlWindows, StartRow:=1, DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, _
ConsecutiveDelimiter:=True, Tab:=False, Semicolon:=True, Comma:=False, _
Space:=False, Other:=False
ActiveWorkbook.SaveAs Left(.FoundFiles(i), Len(.FoundFiles(i)) - 4), FileFormat:=xlNormal
ActiveWorkbook.Close SaveChanges:=True
Next i
End If
End With
End Sub

 

[Sebwan]

Re : changer l'extension pour une collection de fichier

Merci beaucoup pour vos aides!