Calculer un rang avec conditions multiples

[ApprentieXLS]

Bonjour à tous,

je cherche désespéramment à calculer un rang en fonction d'un critère qui évolue : j'ai 4 colonnes (manager, magasin, note, rang) et je souhaite que la dernière colonne indique le rang du magasin parmi les magasins du manager uniquement. Comme il y a plus de 40 managers et pour ne pas modifier la plage de données dès qu'un magasin est rajouté il faut vraiment que je puisse automatiser le calcul du rang.
Dans le document joint, pour que ma question soit plus claire j'ai mis en colonne E ce que je souhaiterai avoir comme résultats via la formule qui serait en D.

Un grand merci par avance

ApprentieXls

 

[mapomme]

Re : Calculer un rang avec conditions multiples

Bonjour ApprentieXLS et bienvenue sur XLD ,

Un essai dans le fichier joint.

La formule en D3 (à tirer/copier vers le bas) est une formule matricielle à valider par Ctrl+maj+Entrée:

=NB(SI($A$3:$A$23=A3;$C$3:$C$23;""))+1-SOMME(--(C3>=SI($A$3:$A$23=A3;$C$3:$C$23;"")))

rem: la formule gère les ex aequo (11%, 10%, 10%, 9% doit donner les rangs 1, 2, 2, 4)

Formule matricielle: Elle doit être validée par la combinaison des touches Ctrl+Maj+Entrée au lieu de la seule touche Entrée comme une formule classique.
Si la validation matricielle est correcte, alors Excel entoure la formule d'accolades {=.......}.
Chaque fois que cette formule sera modifiée, la validation devra se faire par Ctrl+Maj+Entrée. Les accolades apparaissent à la validation et ne doivent pas être saisies au clavier.

 

[R@chid]

Re : Calculer un rang avec conditions multiples

Bonsoir et Bienvenue sur XLD,
Bonsoir mapomme
sauf erreur de ma part, je vois que tu t'es compliqué la vie.
en D3 :

=NB.SI.ENS(A$3:A$23;A3;C$3:C$23;">="&C3)

@ tirer vers le bas


@ + +

 

[mapomme]

Re : Calculer un rang avec conditions multiples

Bonjour R@chid ,

(...) je vois que tu t'es compliqué la vie. en D3 : =NB.SI.ENS(A$3:A$23;A3;C$3:C$23;">="&C3) (...)

Comme souvent je fais dans le tordu et biscornu . De plus, fréquemment, j'oublie le NB.SI.ENS Mais pour tenir compte des ex aequo, ne peut pas adapter ta formule comme suit ? :

=1+NB.SI.ENS(A$3:A$23;A3;C$3:C$23;">"&C3)

 

[Monique]

Re : Calculer un rang avec conditions multiples

Bonjour,

40 caractères (idem Nb.Si.Ens)
=SOMMEPROD((A$3:A$23=A3)*(C$3:C$23>=C3))


36 caractères, à valider par ctrl, maj et entrée :
=SOMME((A$3:A$23=A3)*(C$3:C$23>=C3))

 

[ApprentieXLS]

Re : Calculer un rang avec conditions multiples

Bonjour à tous,

un grand merci pour votre aide : R@chid, je n'avais pas du tout pensé à la formule nb.si.ens (j'étais restée bloquée sur la formule rang..). Ce compteur intelligent est parfait et simple à comprendre pour moi (plus que la formule matricielle je dois le reconnaître). J'ai repris la version de mapomme (1+ NB.SI.ENS etc.) pour avoir un compteur qui commence à 1 et non à 0.

Encore merci

 

[R@chid]

Re : Calculer un rang avec conditions multiples

Bonsoir @ tous,

Mapomme :
j'ai pas compris ton truc des exæquos, nos 2 formules renvoient le même résultat
sinon cette formule gère bien les exæquos :

=NB.SI.ENS(A$3:A$23;A3;C$3:C$23;">"&C3)+NB.SI.ENS(A$3:A3;A3;C$3:C3;C3)

ApprentieXLS :
merci de prendre le temps de me montrer le problème de 0 dont tu parles, moi j'ai fait avec ">="&C3 et pas ">"&C3 donc on jamais avoir de 0.

@ + +

 

[mapomme]

Re : Calculer un rang avec conditions multiples

Bonsoir à tous, R@chid

(...) j'ai pas compris ton truc des exæquos, nos 2 formules renvoient le même résultat

R@chid,

Voir le classements suivant les deux formules dans le fichier joint.

 

[ApprentieXLS]

Re : Calculer un rang avec conditions multiples

Bonjour R@chid,

tu as raison j'ai fait un mix des deux formules : pas de problème de rang à 0 avec ">". Par contre merci à nouveau pour la formule modifiée avec les exaequos : je l'ai modifié avec toutes mes conditions supplémentaires et ça fonctionne très bien.

un grand merci

 

[Celedo]

Re : Calculer un rang avec conditions multiples

Bonsoir et Bienvenue sur XLD,
Bonsoir mapomme
sauf erreur de ma part, je vois que tu t'es compliqué la vie.
en D3 :

=NB.SI.ENS(A$3:A$23;A3;C$3:C$23;">="&C3)

@ tirer vers le bas


@ + +

Bonjour, je réactive ce vieux post ... j'ai un cas similaire au problème initial. J'ai donc utilisé la formule telle qu'elle est expliquée juste au-dessus en l'adaptant à mon tableau. Ça marche, donc très bien. Par contre, je ne comprends pas bien comment marche la 2eme condition (">="&C3). Donc par curiosité, j'aimerai bien comprendre la logique de tout ça. Merci.