Calcul de redevance sur chiffre d'affaire selon différentes conditions

nina2345

XLDnaute Nouveau
Bonjour,

Je suis face à un problème. Je dois calculer une redevance sur un chiffre d'affaire de 800 000 euros d'après les conditions suivantes :
- entre 0€ et 500 000€ la redevance sera de 15% sur la partie du CA concernée
- entre 500 001 et 700 000 € la redevance sera de 10% sur la partie du CA concernée
- entre 700 001€ et plus la redevance sera de 15% sur la partie du CA concernée

J'ai essayé de modeliser mon calcul avec la formule suivante mais le résultat n'est pas bon, j'ai du faire une erreur :

=SI(ET(B16>0;B16<=500000);B16*15%;SI(ET(B16>=500001;B16<=700000);B16*10%;SI(B16>=700001;B16*15%;"")))

Sachant que B16 est le CA de 800 000€

Merci d'avance pour votre aide.
 
Dernière édition:

néné06

XLDnaute Accro
Re : Calcul de redevance sur chiffre d'affaire selon différentes conditions

Bonjour Nina et bienvenue sur le Forum,

Regardes cette pièce-jointe et dis-nous ?

A+

René
 

Pièces jointes

  • Classeur1.xlsx
    9.8 KB · Affichages: 51
  • Classeur1.xlsx
    9.8 KB · Affichages: 46
  • Classeur1.xlsx
    9.8 KB · Affichages: 50

CISCO

XLDnaute Barbatruc
Re : Calcul de redevance sur chiffre d'affaire selon différentes conditions

Bonjour

Une possibilité parmi d'autres
B16*CHOISIR(EQUIV(B16;{0;500000;700000};1);15;10;15)/100
si le % porte sur le total, et pas uniquement sur la tranche.


Et si on fait par tranche
=MIN(E2;500000)*0,15+MAX(0;MIN(E2;700000)-500000)*0,1+MAX(0;E2-700000)*0,15

@ plus
 
Dernière édition:

st007

XLDnaute Barbatruc
Re : Calcul de redevance sur chiffre d'affaire selon différentes conditions

Bon dimanche,
=si(et(B16>500001;B16<700000);B16*0.1;B16*0.15)

edit : bonjour et bon dimanche, y a du monde quand même ...
 
Dernière édition:

nina2345

XLDnaute Nouveau
Re : Calcul de redevance sur chiffre d'affaire selon différentes conditions

Merci Nené pour ta réponse ;) et puis quelle réactivité, c'est super ca me parait très bien tout ça .

J'aimerai juste comprendre un petit truc :
=SI(ET(B1>0;B1<=500000);B1*0,15;SI(ET(B1>=500001;B1<=700000);((B1-500000)*0,1)+(75000);SI(B1>=700001;((B1*0,15)-10000);"")))

A quoi correspond le 75000 que tu ajoutes dans la deuxième condition? Si je comprends cela, je pourrai de nouveau appliquer cette formule toute seule dans d'autres cas de figure.

Merci ;)
 
Dernière édition:

CISCO

XLDnaute Barbatruc
Re : Calcul de redevance sur chiffre d'affaire selon différentes conditions

Bonjour

75000= 500000*0,15, c'est à dire la redevance sur la partie inférieure à 500 000.

@ plus

P.S : Cf. ma seconde proposition, un peu plus courte.
 

néné06

XLDnaute Accro
Re : Calcul de redevance sur chiffre d'affaire selon différentes conditions

re,

Les 75000 correspondent à la tranche que tu dois de 0 jusqu'à 500000, après nous avons 10% de 500001 à 700000.

A+

René

Edit:

Bien le bonjour Cisco ,St007
 

nina2345

XLDnaute Nouveau
Re : Calcul de redevance sur chiffre d'affaire selon différentes conditions

En comparant vos différentes méthodes, je me suis aperçue que la méthode la plus précise était celle de CISCO.

=MIN(E2;500000)*0,15+MAX(0;MIN(E2;700000)-500000)*0,1+MAX(0;E2-700000)*0,15

Je pense utiliser celle-ci du coup car sinon il y a pas mal de différence en terme de résultat.

merci en tout cas à toutes vos réponses
 

néné06

XLDnaute Accro
Re : Calcul de redevance sur chiffre d'affaire selon différentes conditions

Re,

Perso, je constate les mêmes résultats ?

A+

René
 

Pièces jointes

  • Classeur1.xlsx
    16.6 KB · Affichages: 41
  • Classeur1.xlsx
    16.6 KB · Affichages: 46
  • Classeur1.xlsx
    16.6 KB · Affichages: 47

CISCO

XLDnaute Barbatruc
Re : Calcul de redevance sur chiffre d'affaire selon différentes conditions

Bonjour

Une petite explication au sujet de la mienne :
=MIN(E2;500000)*0,15+MAX(0;MIN(E2;700000)-500000)*0,1+MAX(0;E2-700000)*0,15
Si E2 est inférieur à 500 000, on doit faire le calcul uniquement pour la première tranche, ce qui donne E2*0,15+0+0
MAX(0;MIN(E2;700000)-500000) = 0 car MIN(E2;700000)-500000 est négatif car E2 est inférieur à 500 000
MAX(0;E2-700000)*0,15 = 0 car E2 - 700 000 est négatif.
Si E2 est compris entre 500 001 et 700 000, on fait 500 000*0,15+(E2 - 500 000) * 0,1+0
Si E2 est supérieur à 700 000, on fait 500 000*0,15+(700 000 - 500 000) * 0,1+(E2 - 700 000) * 0.15

@ plus

PS : Cette formule n'est pas plus précise que les autres. Elle donne le même résultat que d'autres, avec une autre méthode, c'est tout.

PS : Bonsoir Victor21 :)
 
Dernière édition:

Victor21

XLDnaute Barbatruc
Re : Calcul de redevance sur chiffre d'affaire selon différentes conditions

Re,

Cisco tu as raison : une explication n'est jamais superflue:)

J'ap pris le contre-pied de mes camarades en appliquant 15% sur l'ensemble, et en déduisant de ce résultat 5% sur la partie appartenant à la tranche 500000-700000, si elle existe :)