Microsoft 365 Cacher tout sauf la feuille

Aloha

XLDnaute Accro
Bonjour,
Y a-t-il moyen de cacher toute la partie supérieure d'Excel, en ne laissant apparents que la feuille et les onglets?
Bien à vous
Aloha
 

sylvanu

XLDnaute Barbatruc
Supporter XLD
Re,

Pour le premier point, c'est moi qui est mer....
Voici une V2. En fait c'est :
VB:
Private Sub Workbook_BeforeClose(cancel As Boolean)
et non
Private Sub Workbook_Close()
J'ai mis un Msgbox pour tester.

C'est vrai que ça ne sert à rien si vous quittez XL.
Par contre si vous ne fermez que ce fichier alors les menus reviennent pour les autres.
 

Pièces jointes

  • Desactivation (V2).xlsm
    17.3 KB · Affichages: 6

Aloha

XLDnaute Accro
J'ai fermé Excel! En effet, je n'ai pas considéré l'autre situation.

Autre question: y a-t-il moyen de garantir que, si les menus sont cachés pour ce fichier, ils ne le sont pas pour d'autres fichiers ouverts et dans lesquels on a besoin des menus?
 

sylvanu

XLDnaute Barbatruc
Supporter XLD
10441285_712869212107935_2686764097783673539_n.jpg
Si, si, je suis extrêmement précoce !
 

patricktoulon

XLDnaute Barbatruc
bonsoir
le soucis avec displayfullscreen c'est qu'il es facilement contournable
soit par double click sur la caption , la touche esc , le bouton sortir du plein ecran de menu cell , etc.. et il y en a plein d'autre

le show ribbon est une meilleure solution combiné a windowstate et les display

voici un exemple
prenez un fichier vierge

dans le module thisworkbook collez ceci
VB:
Private Sub Workbook_BeforeClose(Cancel As Boolean)
NoFullscreen
Application.CommandBars("Cell").Reset
End Sub

Private Sub Workbook_Open()
menu
FullscreenA
End Sub

dans un module standard collez cela
VB:
Option Explicit

Sub menu()
   Dim bout As Object
   With CommandBars("cell")
        .Reset
        With .Controls.Add(msoControlButton, before:=1): .Caption = "noFullScreen": .OnAction = "NoFullscreen": End With
        With .Controls.Add(msoControlButton, before:=1): .Caption = "FullScreen": .OnAction = "FullscreenA": End With
    End With
End Sub
Sub FullscreenA()
    With Application
        '.DisplayFullScreen = true' il est facilement trompable et contournable
        '.ScreenUpdating = False:
        '.DisplayGridlines = True
        .DisplayFormulaBar = False
        .DisplayStatusBar = False
        .WindowState = xlMaximized
    End With

    With ActiveWindow
        .DisplayHeadings = False: .DisplayGridlines = True
        .DisplayHorizontalScrollBar = False: .DisplayVerticalScrollBar = False
        '.DisplayWorkbookTabs = False
    End With
    Application.ExecuteExcel4Macro "Show.Toolbar(""Ribbon"", false)"

    With CommandBars("cell"): .Controls(1).Enabled = False: .Controls(2).Enabled = True: End With
End Sub

Sub NoFullscreen()
    With Application
        '.DisplayFullScreen = False' il est facilement trompable et contournable
        '.ScreenUpdating = False:
        '.DisplayGridlines = True
        .DisplayStatusBar = True
        .DisplayFormulaBar = True
        .WindowState = xlNormal
    End With

    With ActiveWindow
        '.DisplayGridlines = True
        .DisplayHeadings = True
        .DisplayHorizontalScrollBar = True
        .DisplayVerticalScrollBar = True
        .DisplayWorkbookTabs = True
    End With
    Application.ExecuteExcel4Macro "Show.Toolbar(""Ribbon"", true)"
    With CommandBars("cell"): .Controls(1).Enabled = True: .Controls(2).Enabled = False: End With
End Sub

voila a l'ouverture vous etes en fullscreen sans menu et autres display sauf les onglets
vous avez les boutons dans le menu click droit sur cellule pour faire et redéfaire


double click ou pas , touche esc ou pas le menu walouh walouh ;)
 

Aloha

XLDnaute Accro
Re,
C'est super!
Et cette méthode ne comporte pas de risques, p.ex en cas de plantage d'Excel?
En tout cas elle permet d'avoir en même temps des fichiers ouverts en fullscreen et d'autres avec les menus affichés, ce qui est un grand avantage!
Bonne soirée
Aloha
 

Aloha

XLDnaute Accro
J'avais trouvé encore une autre méthode, qui fait que le camouflage et le dé-camouflage se font à l'activation et à la désactivation, ce qui a comme avantage au code initial que si je passe de ce classeur à un autre classeur ouvert, les menus sont affichés pour le deuxième classeur; si je repasse au premier ils sont à nouveau cachés.
Pas mal non plus.

VB:
Private Sub Workbook_Activate()
    Application.ExecuteExcel4Macro "Show.Toolbar(""Ribbon"", False)"
End Sub

Private Sub Workbook_Deactivate()
    Application.ExecuteExcel4Macro "Show.Toolbar(""Ribbon"", True)"
End Sub
 
Dernière édition:

Discussions similaires

Réponses
8
Affichages
196

Statistiques des forums

Discussions
311 724
Messages
2 081 936
Membres
101 844
dernier inscrit
pktla