Balance avec NBCAR et recherche Libéllés

toune21

XLDnaute Impliqué
Bonjour,

Vous êtes toujours la pour moi et MERCI d'avance,

J'ai une balance générale et je me suis fais un onglet "BB" pour récupérer les sommes avec NBCAR et SOMMEPROD.

Je souhaiterais récupérer les libellés de l'onglet Plan.
Dans ma colonne Choix Cpt , je serais appelée à saisir : 1, 2 ou 3 Caractères.
J'ai essayé avec
GAUCHE(RECHERCHEV.....NBCAR
RECHERCHEV(NBCAR(GAUCHE.....
et j'ai souvent une #NA ou #VALEUR.... ?

Pouvez-vous m'aider ?
Ci-dessous la boule de cristal
Cordialement,
 

Pièces jointes

  • Balance.xls
    66 KB · Affichages: 51
  • Balance.xls
    66 KB · Affichages: 49
  • Balance.xls
    66 KB · Affichages: 44

job75

XLDnaute Barbatruc
Re : Balance avec NBCAR et recherche Libéllés

Bonjour toune21,

En BB!B4 formule matricielle à tirer vers le bas :
Code:
=SIERREUR(INDEX(PlanOrig;EQUIV(""&A4;GAUCHE(INDEX(PlanOrig;;1);NBCAR(A4));0);3);"")
à valider par Ctrl+Maj+Entrée.

Sur les versions antérieures à Excel 2007 SIERREUR n'existe pas, on utilisera, toujours en matriciel :

Code:
=SI(ESTNA(EQUIV(""&A4;GAUCHE(INDEX(PlanOrig;;1);NBCAR(A4));0));"";INDEX(PlanOrig;EQUIV(""&A4;GAUCHE(INDEX(PlanOrig;;1);NBCAR(A4));0);3))
A+
 

job75

XLDnaute Barbatruc
Re : Balance avec NBCAR et recherche Libéllés

Re,

Dans la mesure où les numéros de comptes ont toujours 7 chiffres, formule normale en B4 :
Code:
=SIERREUR(RECHERCHEV(A4*10^(7-NBCAR(A4));PlanOrig;3;0);"")
ou encore :
Code:
=SI(NB.SI(INDEX(PlanOrig;;1);A4*10^(7-NBCAR(A4)));RECHERCHEV(A4*10^(7-NBCAR(A4));PlanOrig;3;0);"")
A+
 

toune21

XLDnaute Impliqué
Re : Balance avec NBCAR et recherche Libéllés

Re,
Les 2 formules matricielle fonctionnent.

Re,
Dans la mesure où les numéros de comptes ont toujours 7 chiffres, formule normale en B4 :
A+

Effectivement tous les numéros ont 7 chiffres, donc je vais essayer celles-ci et je reviens pour confirmer.

J'ai une question aussi, est-ce qu'il faut que je note RESOLU ?
A plus
 

Discussions similaires

Réponses
5
Affichages
1 K