XL 2016 Autre curiosité ComboBox

[Dudu2]

Bonjour,

J'aimerais que le ComboBox.DropDown s'exécute automatiquement à chaque fois qu'on entre dans une ComboBox.
J'ai donc codé:

Private Sub UserForm_Initialize()
    Me.ComboBox1.List = [A1:A3].Value
    Me.ComboBox2.List = [B1:B3].Value
    Me.ComboBox3.List = [C1:C3].Value
    Me.ComboBox1.SetFocus
End Sub

Private Sub ComboBox1_Enter()
    [I2].Value = "ComboBox1_Enter"
    Me.ComboBox1.DropDown
End Sub

Private Sub ComboBox2_Enter()
    [I2].Value = "ComboBox2_Enter"
    Me.ComboBox2.DropDown
End Sub

Private Sub ComboBox3_Enter()
    [I2].Value = "ComboBox3_Enter"
    Me.ComboBox3.DropDown
End Sub

Hélas ! Quand on utilise Tabulation pour passer à la ComboBox suivante, le ComboBox.DropDown ne s'exécute qu'une fois sur 2. Et pourquoi donc ?

 

[patricktoulon]

re
chez moi ça s’exécute qu'a partir de la 3 et si je continue avec tab ca passe a la 2 puis 1 puis etc.....

peut être justement parce que des events sont implémentés et bloquent ce type de fonctionnement de base

 

[Dudu2]

Je pense que c'est à cause du fait que le DropDown de la ComboBox précédente est actif au moment de [Tab].
Mais alors que faire dans l'Exit ou l'Enter suivant pour "dédropper" la ComboxBox qu'on quitte ?

 

[laurent950]

Bonjour @Dudu2 @patricktoulon @mapomme

Pour désactivé l'évènement et le réactivé :
il faut stocké une variable dans une classe (j'ai créer un module de classe : stopEvent)
J'ai pas trouvé d'autre solution
Impossible de créer une variable Public dans des modules Privés (d'où se module de classe)
et cela fonctionne très bien mais c'est copieux (juste pour stocké une variable Boolean)

Private ClsFlag As Boolean
Property Let GestEvent(ByVal Flag As Boolean)
'Désactivation de l'événement = True
    ClsFlag = Flag
End Property
Property Get GestEvent() As Boolean
' Premiére Opération
'Désactivation de l'événement = True
    GestEvent = ClsFlag
' Réactive l'évenemnt pour la suite
    If ClsFlag = True Then ClsFlag = False
End Property

et le code dans le module Userform

Option Explicit
Public ActDesaEven As New stopEvent
Private Sub UserForm_Initialize()
'Désactivation de l'événement = True
ActDesaEven.GestEvent = True
Me.ComboBox1.List = [A1:A3].Value
Me.ComboBox2.List = [B1:B3].Value
Me.ComboBox3.List = [C1:C3].Value
'Me.ComboBox1.SetFocus
End Sub
'
Private Sub ComboBox1_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
'Si l'événement est déjà en cours : exit !
If ActDesaEven.GestEvent = True Then Exit Sub
[I2].Value = "ComboBox1_Enter"
If KeyCode = vbKeyTab Then Me.ComboBox1.DropDown
End Sub
'
Private Sub ComboBox2_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
'Si l'événement est déjà en cours : exit !
If ActDesaEven.GestEvent = True Then Exit Sub
[I2].Value = "ComboBox2_Enter"
If KeyCode = vbKeyTab Then Me.ComboBox2.DropDown
End Sub
'
Private Sub ComboBox3_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
'Si l'événement est déjà en cours : exit !
If ActDesaEven.GestEvent = True Then Exit Sub
[I2].Value = "ComboBox3_Enter"
If KeyCode = vbKeyTab Then Me.ComboBox3.DropDown
End Sub

cdt

 

[patricktoulon]

re
a oui y a de le recherche Laurent
mais ça fait exactement le même effet que Dudu2 a savoir
tab sur la 1 active la 2 sans dropdown
tab sur la 2 active la 3 et dropdown
tab sur la 3 active la 1 sans dropdown
et enfin a nouveau tab sur la 1 active la 2 avec dropdown

 

[patricktoulon]

re
@mapomme ca fait le job

 

[mapomme]

Re,

J'ai supprimé par mégarde le mauvais message
Je le publie à nouveau sinon on ne comprend pas le message ci-dessus de @patricktoulon .

 

[patricktoulon]

re

Option Explicit

Private Sub ComboBox1_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    With ComboBox1
        If Val(.Tag) = 0 Then .Tag = 1
        If .Tag = 1 Then .Tag = 0: .DropDown
    End With
End Sub


Private Sub ComboBox2_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    With ComboBox2
        If Val(.Tag) = 0 Then .Tag = 1
        If .Tag = 1 Then .Tag = 0: .DropDown
      End With
End Sub

Private Sub ComboBox3_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    With ComboBox3
        If Val(.Tag) = 0 Then .Tag = 1
        If .Tag = 1 Then .Tag = 0: .DropDown
    End With
End Sub



Private Sub UserForm_Initialize()
    Columns("i:i").Clear
    Me.ComboBox1.List = [A1:A3].Value
    Me.ComboBox2.List = [B1:B3].Value
    Me.ComboBox3.List = [C1:C3].Value
    TextBox1.SetFocus
End Sub

ce qui prouve bien que c'est bien depuis le debut une question d'events

même si les events ne sont pas utilisés dans le code l'instance de classe interne de l'object est bien instanciée et donc tout ses events dispo

 

[Dudu2]

Vous êtes très fort !

 

[jcf6464]

Bonsoir Dudu2,Mapomme,patricktoulon, laurent950 et le forum

Peut être comme cela

Private Sub ComboBox1_MouseMove(ByVal Button As Integer, ByVal Shift As Integer, ByVal x As Single, ByVal Y As Single)
        ComboBox1.DropDown
End Sub

bonne continuation jcf6464

 

[Dudu2]

Bon je me suis un peu embrouillé dans ma première interprétation

J'ai utilisé la version de @mapomme (en limitant à 1 ou 2 KeyCodes).

Mais y a un truc que je ne comprends pas...
Au lancement du UserFom1, l'évènement ComboBox1_Enter est déclenché et pourtant le ComboBox1.ScrollDown ne se fait pas. Alors que j'ai un autre classeur dans lequel ça marche parfaitement.
Il a fallu que je bidouille un flag pour laisser le ComboBox1_KeyUp (qui reçoit KeyCode = 255 au lancement) faire le boulot.

 

[Dudu2]

@jcf6464, oui cela je l'ai essayé et ça marche bien. Mais cela a quelques inconvénients et c'est pour ça que je suis passé sur l'évènement Enter().
Par exemple si un ComboBox1.DropDown est déclenché par le MouseMove(), on ne peut pas en sortir en passant la souris sur une autre ComboBox. Ou alors en sortir avec un clic ou Tab.
Donc on doit mixer clavier et souris pour passer de l'un à l'autre.
De plus on peut passer la souris involontairement sur la ComboBox, cela se déclenche et il faut en sortir.

 

[Dudu2]

Sinon il y a une solution un peu basique mais qui fonctionne: envoyer F4 comme documenté ici.
Et là c'est trivial.

Private Sub UserForm_Initialize()
   Me.ComboBox1.List = [A1:A3].Value
   Me.ComboBox2.List = [B1:B3].Value
   Me.ComboBox3.List = [C1:C3].Value
End Sub

Private Sub ComboBox1_Enter()
    SendKeys "{F4}" 'DropDown
End Sub

Private Sub ComboBox2_Enter()
    SendKeys "{F4}" 'DropDown
End Sub

Private Sub ComboBox3_Enter()
    SendKeys "{F4}" 'DropDown
End Sub

 

[patricktoulon]

purée dudu2 si tu continu a filer mauvais cotton tu va m'entendre chanter toi !!!!

Private Sub UserForm_Initialize()
   Me.ComboBox1.List = [A1:A3].Value
   Me.ComboBox2.List = [B1:B3].Value
   Me.ComboBox3.List = [C1:C3].Value
End Sub

Private Sub ComboBox1_Enter()
    CreateObject("wscript.shell").SendKeys "{F4}" 'DropDown
End Sub

Private Sub ComboBox2_Enter()
 CreateObject("wscript.shell").SendKeys "{F4}" 'DropDown
End Sub

Private Sub ComboBox3_Enter()
 CreateObject("wscript.shell").SendKeys "{F4}" 'DropDown
End Sub

 

[Dudu2]

Je te demande pardon mon Patrick, je recommencerai plus

J'ai corrigé le fichier pour sortir de l'infamie