XL 2019 ANALYSE VALEUR MINIMUM ET SYNTHESE

[cdiemcarpe4]

Bonjour à tous ,

Je souhaiterai récupérer la valeur minimum de l'article dans la colonne B tout en conservant les données associés aux colonnes C D et E qui sont liées à la recherche de la valeur minimum trouvée .
J'ai essayé une rechercheH et V imbriquée , et dans un rapport de croisé dynamique mais cela calcule la valeur minimum en colonne B mais sans me reprendre celle des valeurs en C D et E, une âme charitable aurait-il une idée pour faire une synthèse efficace?

Je vous ais joint le fichier en question pour pour plus de clarté

Merci d'avance

 

[JHA]

Bonjour à tous,

Un essai par TCD

JHA

 

[cdiemcarpe4]

Merci JHA , j'ai oublié de préciser que je ne veux que s'affiche que les valeurs minimum avec les infos en C , D et E car après je vais me servir d'une rechercheV pour l'extraction des données , auriez-vous une solution?

 

[JHA]

Bonjour à tous,

TCD modifié

JHA

 

[job75]

Bonsoir cdiemcarpe4, JHA,

Une solution VBA dans le fichier joint avec cette macro dans le code de la feuille SYNTHESE :

Private Sub Worksheet_Activate()
Dim ncol%, tablo, resu(), d As Object, i&, x$, lig&, j%, n&
With Sheets("MATRICE").[A1].CurrentRegion 'adapter éventuellement
    ncol = .Columns.Count
    If ncol = 1 Then ncol = 2 'au moins 2 cellules
    tablo = .Resize(, ncol)
End With
ReDim resu(1 To Rows.Count, 1 To ncol)
Set d = CreateObject("Scripting.Dictionary")
For i = 2 To UBound(tablo)
    x = tablo(i, 1)
    If d.exists(x) Then
        lig = d(x)
        If tablo(i, 2) < resu(lig, 2) Then
            For j = 1 To ncol: resu(lig, j) = tablo(i, j): Next j
        End If
    Else
        n = n + 1
        d(x) = n 'mémorisation
        For j = 1 To ncol: resu(n, j) = tablo(i, j): Next j
    End If
Next i
'---restitution---
If FilterMode Then ShowAllData 'si la feuille est filtrée
With [A2] '1ère cellule de restitution, adapter éventuellement
    If n Then
        .Resize(n, ncol) = resu
        .Resize(n, ncol).Borders.Weight = xlThin 'bordures
    End If
    .Offset(n).Resize(Rows.Count - n - .Row + 1, ncol).Delete xlUp 'RAZ en dessous
End With
Columns.AutoFit 'ajustement largeurs
With UsedRange: End With 'actualise la barre de défilement verticale
End Sub

Elle se déclenche quand on active la feuille.

A+

 

[cdiemcarpe4]

Merci beaucoup à tous , je vais soutenir ce forum cela m'a économisé beaucoup de temps , JOB75 ce VBA est parfait