Aide SOMMEPROD conditions imbriquées multiples ET/OU

[Lostro]

Bonjour à tous, dans le cadre de mon stage je me heurte au problème suivant:

	A	B	C	D	E	F
1	1	1	1	1	1	1
2	1	1	1	0	0	0
3	0	0	0	1	1	1
4	0	0	0	0	0	0

J'ai 2 jeux de valeurs: ABC et DEF.
J'aimerai faire par exemple la somme du nombre de lignes où : ABC=111 OU DEF=111. La formule devrai aussi marcher pour toutes les combinaisons(111, 101, 100, 001, 000 et 010) .
Dans le tableau ci dessus, le nombre de lignes ou 111 aparait est de 3.
J'ai pensé à utiliser SOMMEPROD mais mes recherches durent depuis des heures et restent infructueuses, je me tourne donc vers vous.
Voilà où j'en suis : SOMMEPROD(((A1:A4=1)*(B1:B4=1)*(C1:C4=1))+((D14=1)*(E1:E4=1)*(F1:F4=1)))
Avec ma formule, la ligne 1 est comptée deux fois car mon " + " est considéré comme une addition je crois, j'obtiens 4 au lieu de 3.
Comment pourrai-je obtenir le résultat attendu ?

Pouvez-vous m'aider s'il vous plait ?
Merci pour votre temps,
Amicalement, Lostro

 

[JHA]

Bonjour à tous,

Pas sur de comprendre

=SOMMEPROD((B2:D4=1)*(E2:G4=1))

ou

=SOMMEPROD((B2:D2=1)*(E2:G2=1))

copier vers le bas

JHA

 

[ODVJ]

bonsoir à tous,

une idée en passant : =SOMMEPROD(--(PRODUITMAT(A1:F4;{1.0;1.0;1.0;0.1;0.1;0.1})=3))

cordialement

 

[Lostro]

Bonsoir à tous,
Merci de vos réponses
Malheureusement aucunes de vos pistes ne répond à mon problème,
J'ai modifié mon énoncé en espérant être plus clair.

Cordilement

 

[ODVJ]

qu'à cela ne tienne :

=SOMMEPROD(--(PRODUITMAT(--(PRODUITMAT(A1:F4;{1.0;1.0;1.0;0.1;0.1;0.1})=3);{1;1})>0))

cdlt

 

[Lostro]

Bonjour les amis!
Encore merci pour vos réponses, j'ai trouvé ce qu'il me fallait, (je n'avais pas pensé à mes formules de proba de lycée )

La formule qui fait le job est donc :

=SOMMEPROD((A1:A4=1)*(B1:B4=1)*(C1:C4=1))+SOMMEPROD((D1:D4=1)*(E1:E4=1)*(F1:F4=1))-SOMMEPROD((A1:A4=1)*(B1:B4=1)*(C1:C4=1)*(D1:D4=1)*(E1:E4=1)*(F1:F4=1))

Bon dimanche,
Lostro

 

[Jocelyn]

Bonjour le Forum,
Bonjour Lostro, JHA , ODVJ,

on peut aussi le faire avec une formule matricielle

=SOMME(SI((A1:A4&B1:B4&C1:C4="111")+(D1:D4&E1:E4&F1:F4="111");1))

et par sommeprod()

=SOMMEPROD(((A1:A4&B1:B4&C1:C4="111")+((A1:A4&B1:B4&C1:C4<>"111")*(D1:D4&E1:E4&F1:F4="111"))))

Cordialement