Agréger deux formules SOMMEPROD(). Pourquoi quand j'étire ça cloche ?

[anthoYS]

Bonjour,

J'ai créer un tableau xbet pour récapituler mes gains... Or, la formule est mauvaise.

si vous voyez quelque chose qui cloche. Je veux additionner totaliser le gain net par mois.

=SOMMEPROD((MOIS(Xbet[Date]=MOIS(Feuil2!B$1))*(ANNEE(Xbet[Date]=ANNEE(Feuil2!B$1))*((Xbet[Gain]-Xbet[Mise])))))

ça m'affiche des nombres fantaisistes ... donc totalement faux. Comment faire afin d'avoir les bons chiffres ?

voyez le fichier joint.

Merci
à+

 

[Dugenou]

Re : Qu'est-ce qui cloche dans ma SOMMEPROD() ?

Bonjour,
Quelques parenthèses manquantes :
=SOMMEPROD((MOIS(Xbet[Date])=MOIS(Feuil2!B$1))*(ANNEE(Xbet[Date])=ANNEE(Feuil2!B$1))*(Xbet[Gain]-Xbet[Mise]))
Cordialement

 

[Jocelyn]

Re : Qu'est-ce qui cloche dans ma SOMMEPROD() ?

Bonjour le Forum,
Bonjour AnthoYs,

Tu avais pas mal de soucis de paranthèse dans ta formule a mettre en B5 de la feuille 2

=SOMMEPROD((MOIS(Xbet[Date])=MOIS(Feuil2!B$1))*(ANNEE(Xbet[Date])=ANNEE(Feuil2!B$1))*Xbet[Gain]-Xbet[Mise])

Cordialement

EDIT : Oup's bonjour Dugenou désolé pas rafraichis après le coup de fil

 

[anthoYS]

Re : Qu'est-ce qui cloche dans ma SOMMEPROD() ?

merci
j'ai voulu agréger deux sommeprod() mais ça ne veux pas valider...

=SOMMEPROD((MOIS(Pinnacle[[Date]:[Date]])=MOIS(B$1))*(ANNEE(Pinnacle[[Date]:[Date]])=ANNEE(B$1))*(Pinnacle[[Gain réel]:[Gain réel]]))+SOMMEPROD((MOIS(Xbet[Date])=MOIS(B$1))*(ANNEE(Xbet[Date])=ANNEE(B$1))*(Xbet[Gain]-Xbet[Mise]))

ça me selectionne ce qui est en bleu + ce message d'erreur :



comment faire pour remédier à ça ?

merci d'avance

 

[anthoYS]

Re : Qu'est-ce qui cloche dans ma SOMMEPROD() ?

merci
j'ai voulu agréger deux sommeprod() mais ça ne veux pas valider...

=SOMMEPROD((MOIS(Pinnacle[[Date]:[Date]])=MOIS(B$1))*(ANNEE(Pinnacle[[Date]:[Date]])=ANNEE(B$1))*(Pinnacle[[Gain réel]:[Gain réel]]))+SOMMEPROD((MOIS(Xbet[Date])=MOIS(B$1))*(ANNEE(Xbet[Date])=ANNEE(B$1))*(Xbet[Gain]-Xbet[Mise]))

ça me selectionne ce qui est en bleu + ce message d'erreur :

Regarde la pièce jointe 360438

comment faire pour remédier à ça ?

merci d'avance

Non c'est bon j'ai trouvé j'avais renommer une colonne Gain-perte au lieu de Gain....

par contre j'ai des #VALEUR! en C5. Pourquoi ?

Pourquoi quand j'étire vers la droite ça m'affiche ça en C5 feuille2 ?

=SOMMEPROD((MOIS(Pinnacle[[Date]:[Date]])=MOIS(C$1))*(ANNEE(Pinnacle[[Date]:[Date]])=ANNEE(C$1))*(Pinnacle[[Gain réel]:[Gain réel]]))+SOMMEPROD((MOIS(Xbet[Objet])=MOIS(C$1))*(ANNEE(Xbet[Objet])=ANNEE(C$1))*(Xbet[Retrait]-Xbet[Gain-Perte]))

je veux date (pas objet) et gain-perte - mise à la place là ou y'a objet, Retrait, gain-perte "Xbet" respectivement...

 

[Jocelyn]

Re : Agréger deux formules SOMMEPROD(). Pourquoi quand j'étire ça cloche ?

re,

Ecris ton 2 eme sommeprod de cette façon en B5 après tu pourras étendre vers la droite

SOMMEPROD((MOIS(Xbet[[Date]:[Date]])=MOIS(Feuil2!B$1))*(ANNEE(Xbet[[Date]:[Date]])=ANNEE(Feuil2!B$1))*(Xbet[[Gain]:[Gain]]-Xbet[[Mise]:[Mise]]))

et tu ne devrais plus avoir de #VALEUR