XL 2010 Afficher onglets d'une liste

[erwanhavre]

Bonjour
Encore besoins de vos lumières ..
voir pj
j'aimerai qu'en appuyant sur les boutons on affiche uniquement les onglets concerné dans la liste.

Exemple: lorsque l'on appuie sur le bouton Jean Jacques on aurai uniquement les onglets Nom1 prénom1 et Nom5 prénom5

est ce faisable ?

Merci

 

[Lone-wolf]

Bonjour erwanhavre, le Forum

@erwanhavre

Mise à part qu'il n'y a aucun bouton, porquoi pas afficher les feuilles par double-clique sur le nom?

 

[erwanhavre]

Bonjour Lone wolf
voir nouvel pj
il s'agit de "formes" auxquelles j'affecterai la macro
pourquoi pas le double clics car ce n'est qu'un exemple de tableau le vrai comporte près de 80 lignes donc plus ou moins 80 onglets à "démasquer" lol

 

[Lone-wolf]

Re

@erwanhavre

J'ai essaié 2 méthodes (Find Next et boucle For) mais sans succès, désolé.

 

[job75]

Bonsoir erwanhavre, Lone-wolf,

Sub Affiche()
Dim prenom$, t, s As Object, nom$, i%
Application.ScreenUpdating = False
With Sheets("Liste")
    prenom = .DrawingObjects(Application.Caller).Text
    t = .[A4].CurrentRegion.Resize(, 6) 'tableau VBA, plus rapide
    For Each s In Sheets
        nom = Replace(s.Name, "é", "e")
        If nom <> .Name Then
            s.Visible = prenom = "Tous"
            For i = 2 To UBound(t)
                If t(i, 1) & " " & t(i, 2) = nom And t(i, 6) = prenom Then s.Visible = xlSheetVisible: Exit For
            Next i
        End If
    Next s
    .Activate
End With
End Sub

Fichier joint.

A+

 

[kingfadhel]

Bonsoir,
Une piste:

// Pour jaques
Sub Jaques()
    Call hidesheets
    Sheets("Nom1 prénom1").Visible = True
    Sheets("Nom5 prénom5").Visible = True
    Sheets("Liste").Select
End Sub

Sub hidesheets()
Dim xWs As Worksheet
    Dim xName As String
    For Each xWs In Application.ActiveWorkbook.Worksheets
        If xWs.Name <> "Liste" Then
            xWs.Visible = xlSheetHidden
        End If
    Next
End Sub

@+

 

[Lone-wolf]

Bonsoir kingfadhel, Gérard

@job75 : il y a un souci avec le prénom philippe, il affiche la feuille Liste.

 

[job75]

@job75 : il y a un souci avec le prénom philippe, il affiche la feuille Liste.

Bah il suffit de ne pas mettre de majuscule sur le bouton... Et d'utiliser la bonne orthographe... Fichier (2).

 

[job75]

Bonjour le fil, le forum,

Fichier (3) avec des cases à cocher :

Sub Affiche()
Dim prenom$, vis As Boolean, t, s As Object, nom$, i%
Application.ScreenUpdating = False
With Sheets("Liste")
    With .DrawingObjects(Application.Caller)
        prenom = .Text
        vis = .Value = xlOn
    End With
    t = .[A4].CurrentRegion.Resize(, 6) 'tableau VBA, plus rapide
    For Each s In Sheets
        nom = Replace(s.Name, "é", "e")
        If nom <> .Name Then
            For i = 2 To UBound(t)
                If t(i, 1) & " " & t(i, 2) = nom And t(i, 6) = prenom Then s.Visible = vis: Exit For
            Next i
        End If
    Next s
    .Activate
End With
End Sub

A+

 

[erwanhavre]

c'est top merci beaucoup