XL 2016 Nombre de jours par mois

Mattb19

XLDnaute Nouveau
Bonjour à tous,

Je me permets de poster un nouveau forum dans l'optique d'avoir une réponse à une problématique concernant le nombre de jours travaillés sur un projet et cela par mois, je m'explique.

J'ai aujourd'hui plusieurs projets qui ont sont définis par un certains nombre de jours à travailler dessus.
Par exemple, le projet A doit être réalisé en 10 jours, tandis que le projet B doit être réalisé en 20 jours, etc...

Ensuite, ces même projets ont une date de début et une date de fin.
Par exemple le projet A commence le 02 janvier 2018 et se termine le 22 février, et puis il en est de même pour les autres projets.

J'ai par la suite, identifié le nombre de jours ouvrés entre la date de début et la date de fin, ce qui nous donne 38 jours ouvrés pour le projet A.

Mon problème se pose à ce moment-là, j'aimerai savoir combien de jours je vais être amené à réaliser en janvier et en février.

Concrètement, il faut savoir combien de jours représente le projet A par rapport au nombre de jours ouvrés (10/38 = 0,26 jours) et ensuite le multiplier par le nombre de jours ouvrés du mois de janvier entre la date de début et la fin du mois.
Dans la théorie, je sais ce qu'il faut faire, mais dans la pratique, je n'arrive pas à l'automatiser, donc si vous avez une idée, je suis preneur et de préférance sans macro.

Merci par avance de votre aide.
Mathieu.
 

Pièces jointes

  • NB_jours_projets_par_mois.xlsx
    12.1 KB · Affichages: 54

fanfan38

XLDnaute Barbatruc
Bonjour,
je t'ai mis ton fichier en pièce jointe avec ma solution... A savoir que je n'ai pas réussi à le mettre en place... cellules nommées... tableau 2 verrouillé... J'utilise la date qui est en entête...
A+ François
 

Pièces jointes

  • NB_jours_projets_par_mois.xlsx
    12.8 KB · Affichages: 53

chris

XLDnaute Barbatruc
Re
Code:
=SI(ET(Tableau2[@[Date de début]:[Date de début]]<=FIN.MOIS(DATEVAL(1&Tableau2[[#En-têtes];[Janvier]]);0);Tableau2[@[Date de fin]:[Date de fin]]>=DATEVAL(1&Tableau2[[#En-têtes];[Janvier]]));Tableau2[@[Nombre de jours de projet]:[Nombre de jours de projet]]/Tableau2[@[Nombre de jours ouvrés travaillés]:[Nombre de jours ouvrés travaillés]]*NB.JOURS.OUVRES(DATEVAL(1&Tableau2[[#En-têtes];[Janvier]]);FIN.MOIS(DATEVAL(1&Tableau2[[#En-têtes];[Janvier]]);0);JoursOuvres);0)
 

Mattb19

XLDnaute Nouveau
Re
Code:
=SI(ET(Tableau2[@[Date de début]:[Date de début]]<=FIN.MOIS(DATEVAL(1&Tableau2[[#En-têtes];[Janvier]]);0);Tableau2[@[Date de fin]:[Date de fin]]>=DATEVAL(1&Tableau2[[#En-têtes];[Janvier]]));Tableau2[@[Nombre de jours de projet]:[Nombre de jours de projet]]/Tableau2[@[Nombre de jours ouvrés travaillés]:[Nombre de jours ouvrés travaillés]]*NB.JOURS.OUVRES(DATEVAL(1&Tableau2[[#En-têtes];[Janvier]]);FIN.MOIS(DATEVAL(1&Tableau2[[#En-têtes];[Janvier]]);0);JoursOuvres);0)

Merci beaucoup pour tout ça, on avance et on arrive presque au bout, mais il y a encore quelques points qui ne fonctionne pas, par exemple, si tu regardes dans le fichier, la somme des mois de janvier et février est égale à un peu plus de 11 alors que cela devrait être égale à 10, j'imagine qu'il y a donc encore un souci avec le mois de février ou cela devrait prendre uniquement les dates entre le 01 février et le 22 février si tu vois ce que je veux dire ?
Dans tous les cas, je te remercie énormément pour l'avancé du sujet
 

Pièces jointes

  • NB_jours_projets_par_mois3.xlsx
    13.4 KB · Affichages: 39

chris

XLDnaute Barbatruc
Re

J'ai repris ce que j'avais fait tout au début ou j'avais calculé des jours (mais pas posté) et appliqué ta règle de trois qui semble correspondre à ce que tu veux
Code:
=SI(ET(Tableau2[@[Date de début]:[Date de début]]<=FIN.MOIS(DATEVAL(1&Tableau2[[#En-têtes];[Janvier]]);0);Tableau2[@[Date de fin]:[Date de fin]]>=DATEVAL(1&Tableau2[[#En-têtes];[Janvier]]));NB.JOURS.OUVRES(MAX(Tableau2[@[Date de début]:[Date de début]];DATEVAL(1&Tableau2[[#En-têtes];[Janvier]]));MIN(FIN.MOIS(DATEVAL(1&Tableau2[[#En-têtes];[Janvier]]);0);Tableau2[@[Date de fin]:[Date de fin]]);JoursOuvres[Jours fériés France])*Tableau2[@[Nombre de jours de projet]:[Nombre de jours de projet]]/Tableau2[@[Nombre de jours ouvrés travaillés]:[Nombre de jours ouvrés travaillés]];0)

NB : on pourrait alléger un peu les formules en nommant diverses parties...
 

Mattb19

XLDnaute Nouveau
Re

J'ai repris ce que j'avais fait tout au début ou j'avais calculé des jours (mais pas posté) et appliqué ta règle de trois qui semble correspondre à ce que tu veux
Code:
=SI(ET(Tableau2[@[Date de début]:[Date de début]]<=FIN.MOIS(DATEVAL(1&Tableau2[[#En-têtes];[Janvier]]);0);Tableau2[@[Date de fin]:[Date de fin]]>=DATEVAL(1&Tableau2[[#En-têtes];[Janvier]]));NB.JOURS.OUVRES(MAX(Tableau2[@[Date de début]:[Date de début]];DATEVAL(1&Tableau2[[#En-têtes];[Janvier]]));MIN(FIN.MOIS(DATEVAL(1&Tableau2[[#En-têtes];[Janvier]]);0);Tableau2[@[Date de fin]:[Date de fin]]);JoursOuvres[Jours fériés France])*Tableau2[@[Nombre de jours de projet]:[Nombre de jours de projet]]/Tableau2[@[Nombre de jours ouvrés travaillés]:[Nombre de jours ouvrés travaillés]];0)

NB : on pourrait alléger un peu les formules en nommant diverses parties...

Merci, merci, merci ......... merci, c'est parfait
Je vais essayer d'alléger comme tu le dis parce que ça fait un peu lourd là

Encore une fois, merci beaucoup !!!!
 

Statistiques des forums

Discussions
311 733
Messages
2 082 009
Membres
101 865
dernier inscrit
MLL