XL 2019 Mettre un "X" automatiquement dans une cellule selon critères valeurs sur la même ligne

C

ced91300

XLDnaute Occasionnel
Bonjour à tous,

j'aurai besoin via (Macro) à ce que que dans une colonne s'affiche automatiquement "X" selon plusieurs critères des valeurs se trouvant sur la même ligne.

merci de votre aide.

Cordialement

Cédric
 

Pièces jointes

  • ced-1.xlsx
    11.6 KB · Affichages: 4
Solution
AtTheOne
ced91300 à dit:
serait-il possible d'avoir la solution dans un module (à la suite d'un VBA déjà existant j'ai 30 feuilles identique) et non dans la feuille pour que cette action se lance en dernier
Cliquez pour agrandir...
Dans ce cas, il faut utiliser la solution de @job75 qui parcourt toute la plage de donnée :
Code
VB: 
Sub ContrôleSaisie(sh As Worksheet)

Dim tablo, i&, x
     With sh.Range("A1", sh.UsedRange).Resize(, 11)
          tablo = .Value 'matrice, plus rapide
          For i = 1 To UBound(tablo)
               x = tablo(i, 3)
               tablo(i, 11) = IIf(tablo(i, 1) = "X" And tablo(i, 2) = "MAISON" And (x = "AA" Or x = "BB" Or x = "CC"), "X", "")
          Next
          Application.EnableEvents = False
          .Columns(11) =...
Trier par date Trier par votes
AtTheOne

AtTheOne

XLDnaute Accro
Supporter XLD
Bonjour à toutes & à tous, bonjour @ced91300
Je re propose une solution par formule et non vba :
En K3
=SI(($A3="X")*($B3="MAISON")*(($C3="AA")+($C3="BB")+($C3="CC"));"X";"")
Je suis sur mon téléphone, je ne peux pas écrire de macro ...
Voir pièce jointe
À bientôt
 

Pièces jointes

  • ced-1.xlsx
    12.1 KB · Affichages: 3
Vote positif 0 Vote négatif
AtTheOne

AtTheOne

XLDnaute Accro
Supporter XLD
Re,
J'ai récuoéré mon PC, voici une version via macro :
le code dans le code de la feuil1 :
VB: 
Private Sub Worksheet_Change(ByVal Target As Range)
     Dim lgn As Long
     If Target.Count = 1 And InStr("-1-2-3-11-", "-" & Target.Column & "-") <> 0 Then
          Application.EnableEvents = False
          lgn = Target.Row
          If UCase(Me.Cells(lgn, 1)) = "X" And UCase(Me.Cells(lgn, 2)) = "MAISON" And InStr("-AA-BB-CC-", "-" & UCase(Me.Cells(lgn, 3)) & "-") <> 0 _
          Then
               Me.Cells(lgn, 11) = "X"
          Else
               Me.Cells(lgn, 11).ClearContents
          End If
          Application.EnableEvents = True
     End If
End Sub

voir le fichier joint
 

Pièces jointes

  • ced-1.xlsm
    16.2 KB · Affichages: 4
Vote positif 0 Vote négatif
AtTheOne

AtTheOne

XLDnaute Accro
Supporter XLD
Bonsoir @ced91300
Bon, sur mon pc ça fonctionne :
1716047018442.gif


Le code est-il au bon endroit :
1716047066007.jpeg


Les événements ne sont-ils pas bloqués ?
Si c'est le cas la macro ne peut pas se dérouler, réactive les avec cette petite macro :
Sub ActiveEvents()
Application.EnableEvents=True​
End Sub

Sinon je ne vois pas ...
Je joins de nouveau le fichier que je viens de tester.

A bientôt
EDIT : Orthographe !!!
 

Pièces jointes

  • ced-1.xlsm
    18 KB · Affichages: 0
Dernière édition:
Vote positif 0 Vote négatif
job75

job75

XLDnaute Barbatruc
Bonjour ced91300, AtTheOne,

Une autre solution avec cette macro dans le code de la feuille :
VB: 
Private Sub Worksheet_Change(ByVal Target As Range)
Dim tablo, i&, x
With Range("A1", UsedRange).Resize(, 11)
    tablo = .Value 'matrice, plus rapide
    For i = 1 To UBound(tablo)
        x = tablo(i, 3)
        tablo(i, 11) = IIf(tablo(i, 1) = "X" And tablo(i, 2) = "MAISON" And (x = "AA" Or x = "BB" Or x = "CC"), "X", "")
    Next
    Application.EnableEvents = False
    .Columns(11) = Application.Index(tablo, , 11)
    Application.EnableEvents = True
End With
End Sub
Elle se déclenche quand on modifie ou valide une cellule quelconque.

Elle est très rapide car elle utilise un tableau VBA.

Nota : la casse est respectée.

A+
 

Pièces jointes

  • ced-1.xlsm
    18.4 KB · Affichages: 1
Vote positif 0 Vote négatif
C

ced91300

XLDnaute Occasionnel
AtTheOne à dit:
Bonsoir @ced91300
Bon, sur mon pc ça fonctionne :
Regarde la pièce jointe 1197118

Le code est-il au bon endroit :
Regarde la pièce jointe 1197119

Les événements ne sont-ils pas bloqués ?
Si c'est le cas la macro ne peut pas se dérouler, réactive les avec cette petite macro :
Sub ActiveEvents()
Application.EnableEvents=True​
End Sub

Sinon je ne vois pas ...
Je joins de nouveau le fichier que je viens de tester.

A bientôt
EDIT : Orthographe !!!
Cliquez pour agrandir...
AtTheOne à dit:
Bonsoir @ced91300
Bon, sur mon pc ça fonctionne :
Regarde la pièce jointe 1197118

Le code est-il au bon endroit :
Regarde la pièce jointe 1197119

Les événements ne sont-ils pas bloqués ?
Si c'est le cas la macro ne peut pas se dérouler, réactive les avec cette petite macro :
Sub ActiveEvents()
Application.EnableEvents=True​
End Sub

Sinon je ne vois pas ...
Je joins de nouveau le fichier que je viens de tester.

A bientôt
EDIT : Orthographe !!!
Cliquez pour agrandir...
bonsoir, oui merci effectivement cela fonctionne impeccablement.

En revanche, je souhaite l'avoir à la suite d'un vba déjà existant dans module et non dans la feuille (j'ai 30 feuilles identique) et quand je lance le vba cela m'efface certains résultats donnés par ta solution.

Merci
 
Vote positif 0 Vote négatif
C

ced91300

XLDnaute Occasionnel
job75 à dit:
Bonjour ced91300, AtTheOne,

Une autre solution avec cette macro dans le code de la feuille :
VB: 
Private Sub Worksheet_Change(ByVal Target As Range)
Dim tablo, i&, x
With Range("A1", UsedRange).Resize(, 11)
    tablo = .Value 'matrice, plus rapide
    For i = 1 To UBound(tablo)
        x = tablo(i, 3)
        tablo(i, 11) = IIf(tablo(i, 1) = "X" And tablo(i, 2) = "MAISON" And (x = "AA" Or x = "BB" Or x = "CC"), "X", "")
    Next
    Application.EnableEvents = False
    .Columns(11) = Application.Index(tablo, , 11)
    Application.EnableEvents = True
End With
End Sub
Elle se déclenche quand on modifie ou valide une cellule quelconque.

Elle est très rapide car elle utilise un tableau VBA.

Nota : la casse est respectée.

A+
Cliquez pour agrandir...
Merci job75

serait-il possible d'avoir la solution dans un module (à la suite d'un VBA déjà existant j'ai 30 feuilles identique) et non dans la feuille pour que cette action se lance en dernier

Merci
 
Vote positif 0 Vote négatif
AtTheOne

AtTheOne

XLDnaute Accro
Supporter XLD
ced91300 à dit:
serait-il possible d'avoir la solution dans un module (à la suite d'un VBA déjà existant j'ai 30 feuilles identique) et non dans la feuille pour que cette action se lance en dernier
Cliquez pour agrandir...
Dans ce cas, il faut utiliser la solution de @job75 qui parcourt toute la plage de donnée :
Code
VB: 
Sub ContrôleSaisie(sh As Worksheet)

Dim tablo, i&, x
     With sh.Range("A1", sh.UsedRange).Resize(, 11)
          tablo = .Value 'matrice, plus rapide
          For i = 1 To UBound(tablo)
               x = tablo(i, 3)
               tablo(i, 11) = IIf(tablo(i, 1) = "X" And tablo(i, 2) = "MAISON" And (x = "AA" Or x = "BB" Or x = "CC"), "X", "")
          Next
          Application.EnableEvents = False
          .Columns(11) = Application.Index(tablo, , 11)
          Application.EnableEvents = True
     End With

End Sub

Sub Appel()
Dim sh As Worksheet
     For Each sh In ThisWorkbook.Worksheets
          'Placer un test ici si toutes les feuilles ne sont pas a traiter par ex
          If sh.Name Like "Tst_##" Then
               ContrôleSaisie sh
          Else
          End If
     Next
End Sub

Voir fichier joint
 

Pièces jointes

  • ced-3.xlsm
    26.6 KB · Affichages: 1
Vote positif 0 Vote négatif
Solution

Discussions similaires

Eric 888
  • Résolu(e)
Microsoft 365 repartir des personnes en deux groupes équilibrés selon plusieurs critères
Réponses
7
Affichages
283
Eric 888
Eric 888
A
  • Question
Microsoft 365 NB.SI selon plusieurs critères
Réponses
3
Affichages
167
al.db
A
P
  • Question
Microsoft 365 Fonction filtre avec si
2 3
Réponses
40
Affichages
1 K
Pulpito
P
Chubby
  • Question
XL 2016 Trouver une valeur selon 3 critères
Réponses
3
Affichages
234
Chubby
Chubby
P
  • Résolu(e)
Autres Choix selon plusieurs critères
Réponses
2
Affichages
203
Pascal22100
P
D
  • Résolu(e)
Microsoft 365 Recherche valeurs sur une même ligne & doublons
Réponses
4
Affichages
153
danielco
D
R
  • Question
Microsoft 365 Incrémenter un nombre dans cellules d'une colonne selon un filtre sur autre cellules dans une colonne.
Réponses
13
Affichages
342
Rom52
R
aspect
  • Question
XL 2019 faire apparaitre une image en fonction d'une valeur vrai
2
Réponses
16
Affichages
217
aspect
aspect
F
  • Résolu(e)
Microsoft 365 Mise en forme conditionnelle selon la référence d'une cellule
Réponses
3
Affichages
234
filiph79
F
A
  • Résolu(e)
XL 2016 Suivant un double-clic sur une cellule, mettre une couleur sur autres cellules.
Réponses
2
Affichages
131
Al1_44
A

Membres actuellement en ligne

10 membres et 131 invités.

Partager cette page

Tutos vidéos

Power Query : Ajouter des requêtes (Excel et Power BI)
Créez votre première fonction LAMBDA dans Excel en 3 étapes!
LAMBDA, l’arme secrète de Microsoft pour Excel !
Office Insider - Découvrez les nouveautés Excel avant tout le monde

Statistiques des forums

Discussions
312 684
Messages
2 090 916
Membres
104 697
dernier inscrit
Pierrot Hubert