PLEIN ECRAN POUR CERTAINS ONGLETS SEULEMENT

sebbbbb · 27 Septembre 2016

Bonjour

étant novice en excel VBA je fais appel a vos conseils.

je souhaite que lorsque j'ouvre un fichier la page à l'ouverture apparaisse en plein écran , c'est a dire sans barre de formule, sans N° de ligne, etc.

j'ai bien trouvé une formule à mettre dans thisworkbook mais le souci c'est que lorsque j'enregistre mon fichier c'est une autre page qui s'ouvre en plein écran que par rapport au fichier modèle et là je ne souhaite pas que le plein écran apparaisse.

en résumé je voudrais choisir les feuilles pour lesquelles ce plein écran apparaisse et pas forcement la page qui s'ouvre par défaut

j'espère être suffisamment clair
merci par avance
seb

chris · 27 Septembre 2016

Bonjour

Ajoute une boucle qui teste le nom de la feuille active et adapte l’affichage en connaissance

sebbbbb · 27 Septembre 2016

merci mais comme mentionné suis novice et ne vois pas a quoi tu fais ref.
peux tu me donner un code ?

Voila ce que j'avais incrit dans myworkbook :

Private Sub Workbook_Open()
Application.DisplayFullScreen = True
' Masquer les en-têtes
ActiveWindow.DisplayHeadings = False
' Masquer les barres de défilement
ActiveWindow.DisplayHorizontalScrollBar = False
ActiveWindow.DisplayVerticalScrollBar = False

End Sub

merci par avance
seb

chris · 27 Septembre 2016

Re

Une solution parmi d'autres

Code:

Private Sub Workbook_Open()
    Select Case ActiveSheet.Name
    Case "Feuil1", "Feuil3" 'les feuilles où l'affichage doit être plein écran
        Call je_cache_ou_pas(False)
    Case Else 'les autres où il faut rétablir l'affichage normal
        Call je_cache_ou_pas(True)
    End Select

End Sub

Sub je_cache_ou_pas(choix As Boolean)
    Application.DisplayFullScreen = Not choix
    ' Masquer les en-têtes
    ActiveWindow.DisplayHeadings = choix
    ' Masquer les barres de défilement
    ActiveWindow.DisplayHorizontalScrollBar = choix
    ActiveWindow.DisplayVerticalScrollBar = choix

End Sub

Cependant si le plein écran doit s'activer ou se désactiver quand on change de feuille c'est plutôt au niveau des événements activate/deactivate que doit se trouver le code...

Evite les titres en majuscules : sur le net MAJUSCULES=HURLER

sebbbbb · 27 Septembre 2016

bjr
oui tu as raison je pense que c'est plus des événements activate / desactivate car d'une feuille a une autre je souhaite que celà fasse apparaitre ou pas le plein écran
sais tu comment faire ?

désolé pour le titre. je ne savais pas
seb

chris · 27 Septembre 2016

Re
Ajoute

Code:

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
    Select Case Sh.Name
    Case "Feuil1", "Feuil3" 'les feuilles où l'affichage doit être plein écran
        Call je_cache_ou_pas(False)
    Case Else 'les autres où il faut rétablir l'affichage normal
        Call je_cache_ou_pas(True)
    End Select

End Sub

Mais si le classeur ne s'ouvre pas forcément toujours sur la même feuille, soit tu gardes le Workbook_Open() ci-dessus, soit tu y mets un code pour activer la feuille voulue.

job75 · 27 Septembre 2016

Bonjour sebbbbb, bienvenue sur XLD, bonjour chris,

Voyez le fichier joint et ces codes dans ThisWorkbook (Alt+F11) :

Code:

Const PleinEcran$ = "Feuil1,Feuil3,Feuil5" 'CodeNames des feuilles en plein écran, à adapter
Dim desactive As Boolean 'mémorisation de la variable

Private Sub Workbook_Activate()
Workbook_SheetActivate ActiveSheet
End Sub

Private Sub Workbook_Deactivate()
desactive = True
Workbook_SheetActivate ActiveSheet
End Sub

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
If Not desactive And InStr("," & PleinEcran & ",", "," & Sh.CodeName & ",") Then
  Application.DisplayFullScreen = True
  Application.DisplayFormulaBar = False 'facultatif
  ActiveWindow.DisplayHeadings = False 'facultatf
  ActiveWindow.DisplayGridlines = False 'facultatf
Else
  desactive = False
  Application.DisplayFullScreen = False
  ActiveWindow.WindowState = xlMaximized
  Application.DisplayFormulaBar = True 'facultatif
  ActiveWindow.DisplayHeadings = True 'facultatf
  ActiveWindow.DisplayGridlines = True 'facultatf
End If
End Sub

Edit : en plein écran, si l'on clique sur l'icône de la barre des tâches on réduit bien sûr la fenêtre.

Si l'on clique de nouveau sur l'icône la fenêtre s'affiche, mais avec le ruban.

A priori il n'y a pas moyen de contrôler cela.

A+

sebbbbb · 27 Septembre 2016

je teste ce soir et te dis
merci en tout cas

job75 · 27 Septembre 2016

Re,

Peut-être nécessaire de préciser : aucun espace dans la liste "Feuil1,Feuil3,Feuil5"...

A+

sebbbbb · 27 Septembre 2016

Bonsoir
sniff
désolé mais celà ne fonctionne pas pourtant j'ai suivi tes instructions à la lettre

voila le code mis dans thisworkbook (workbook - sheet activate)

Const PleinEcran$ = "choix,VL,VL import" 'CodeNames des feuilles en plein écran, à adapter
Dim desactive As Boolean 'mémorisation de la variable

Private Sub Workbook_Activate()
Workbook_SheetActivate ActiveSheet
End Sub

Private Sub Workbook_Deactivate()
desactive = True
Workbook_SheetActivate ActiveSheet
End Sub

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
If Not desactive And InStr("," & PleinEcran & ",", "," & Sh.CodeName & ",") Then
Application.DisplayFullScreen = True
Application.DisplayFormulaBar = False 'facultatif
ActiveWindow.DisplayHeadings = False 'facultatf
ActiveWindow.DisplayGridlines = False 'facultatf
Else
desactive = False
Application.DisplayFullScreen = False
ActiveWindow.WindowState = xlMaximized
Application.DisplayFormulaBar = True 'facultatif
ActiveWindow.DisplayHeadings = True 'facultatf
ActiveWindow.DisplayGridlines = True 'facultatf
End If
End Sub

vois tu le hic

merci
seb

job75 · 27 Septembre 2016

Re,

Le hic saute aux yeux.

Vous avez mis les noms (Names) des feuilles dans la liste au lieu des CodeNames.

Dans mon fichier les feuilles se nomment FA FB FC FD FE FF et la liste c'est "Feuil1,Feuil3,Feuil5".

L'intérêt d'utiliser les CodeNames c'est qu'on peut modifier les noms des feuilles sans inconvénient.

A+

sebbbbb · 27 Septembre 2016

je suis désolé mais celà ne me parle pas beaucoup. j'apprends petit à petit mais pas assez vite pour vous suivre.
qu'est ce qu'un codename. je comprends l'anglais mais ne saisis pas la nuance. pour mi ce devrait être le nom des onglets non ?
si c'est l'ordre des feuilles celà est complique car mon fichier comporte des feuilles cachees que je fais apparaitre ou disparaitre selon des macros.

comment corriger svp

merci
seb

job75 · 27 Septembre 2016

Re,

Quand vous êtes dans VBA, en haut à gauche vous avez le CodeName de chaque feuille, suivi entre parenthèses par son nom (nom de l'onglet).

A+

sebbbbb · 27 Septembre 2016

Génial.
celà marche !!!
vous êtes un génie
mille merci
je fais encore quelques tests et vous confirme qu tout est OK
seb

sebbbbb · 27 Septembre 2016

juste un petit truc
tout marche ok je voudrais juste que pour les feuilles qui ne sont pas concernées par le plein écran celles ci ne soient pas avec quadrillage
merci encore

Effectuez une recherche sur Excel Downloads...

PLEIN ECRAN POUR CERTAINS ONGLETS SEULEMENT

sebbbbb

XLDnaute Impliqué

chris

XLDnaute Barbatruc

sebbbbb

XLDnaute Impliqué

chris

XLDnaute Barbatruc

sebbbbb

XLDnaute Impliqué

chris

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

Pièces jointes

sebbbbb

XLDnaute Impliqué

job75

XLDnaute Barbatruc

sebbbbb

XLDnaute Impliqué

job75

XLDnaute Barbatruc

sebbbbb

XLDnaute Impliqué

job75

XLDnaute Barbatruc

sebbbbb

XLDnaute Impliqué

sebbbbb

XLDnaute Impliqué

Discussions similaires

Membres actuellement en ligne

Partager cette page

Tutos vidéos

Statistiques des forums