Barre d'outils flottante ...

[RENAUDER]

Bonjour,
Création d'une barre d'outils flottante
Lors de l'attribution de la référence d'objet ...
Public Const MyCommandBarName As String = "Présenteisme"
Set cb = Application.CommandBars.Add(MyCommandBarName, msoBarFloating, False, True)
Ce qui marche avec XL2003 (Set cb= ....), plante avec XL2007
Si quelqu'un a trouvé je suis preneur.
D'avance merci

[MichelXld]

bonjour cher Eric


je ne pense pas que les barres d'outils type msoBarFloating soient utilisables sous Excel2007. Tu peux uniquement créer des barres d'outils "fixes" qui s'afficheront dans le ruban: onglet "Complément"

Public Barre As CommandBar
 
Sub TestBarre()
 
    Set Barre = CommandBars.Add("MonMenu", msoBarFloating, False, True)
 
    With Barre.Controls.Add(msoControlButton, 1, , , True)
        .Caption = "Menu 01"
        .FaceId = 50
        .OnAction = "Macro1"
    End With
 
    With Barre.Controls.Add(msoControlButton, 2, , , True)
        .Caption = "Menu 02"
        .FaceId = 49
        .OnAction = "Macro2"
    End With
 
 
    Barre.Visible = True
End Sub
 
Sub Macro1()
    MsgBox "Essai 01"
End Sub
 
Sub Macro2()
    MsgBox "Essai 02"
End Sub
 
Sub SuppressionBarre()
    On Error Resume Next
    Application.CommandBars("MonMenu").Delete
End Sub

Sinon il serait peut etre possible de jouer avec une Barre type PopPup et trouver une astuce pour la réafficher automatiquement en fonction de ton projet (ce style de barre étant masquée après qu'on ai cliqué dessus):

Public Barre As CommandBar
 
Sub TestBarrePopPup()
 
    Set Barre = CommandBars.Add("MonMenu", msoBarPopup, False, True)
 
    With Barre.Controls.Add(msoControlButton, 1, , , True)
        .Caption = "Menu 01"
        .FaceId = 50
        .OnAction = "Macro1"
    End With
 
    With Barre.Controls.Add(msoControlButton, 2, , , True)
        .Caption = "Menu 02"
        .FaceId = 49
        .OnAction = "Macro2"
    End With
 
 
    Barre.ShowPopup 100, 200
End Sub
 
Sub Macro1()
    MsgBox "Essai 01"
    Barre.ShowPopup 100, 200
End Sub
 
Sub Macro2()
    MsgBox "Essai 02"
    Barre.ShowPopup 100, 200
End Sub
 
Sub SuppressionBarre()
    On Error Resume Next
    Application.CommandBars("MonMenu").Delete
End Sub

Quelques infos complémentaires au sujet d'Excel2007:

FAQ MS-Excel - Club d'entraide des développeurs francophones





Bonne journée
MichelXld