.xls vers .doc

[Claudy]

Bonjour,
Un userform dans une feuille .xls....OK, pas de problème.
Comment importer les données de l'USF dans un modèle word aux emplacements prévus("signets" ) de ce doc ?
Auriez vous un petit exemple qui pourrait m'aider?
Merci d'avance et bon dimanche.
Claudy

[joss56]

Bonjour à tous,

As tu essayé:

activedocument.bookmarks("le nom de ton signet").InsertAfter textbox1 (si tes données à transférer se trouve ds un textbox)?
Bonne journée

[tatiak]

Bonjour Claudy, bonjour Joss

Je me permets de proposer ma p'tite méthodologie pour écrire dans word.

Pour ce type de besoin, je crée un document word qui me sert de modèle (ici dans l'exemple ModèleDocument.doc, situé dans un sous répertoire Document), si besoin avec signet (nommé ici "SIGNET_A CREER_DANS_DOCUMENT_WORD") et tableau (ici un seul tableau donc wordDoc.tables(1)).

Dans un premier temps, la macro crée une instance Word et ouvre le modèle :

Sub Vers_Word()
Dim NDF As String, NDF2 As String
Dim WordApp As Word.Application
Dim WordDoc As Word.Document

    NDF = ActiveWorkbook.Path & "\ModèleDocument.doc"
    NDF2 = ActiveWorkbook.Path & "\Document" & Sheets("Feuil1").Range("A1").text & ".doc"
    
    On Error Resume Next
    Set WordApp = CreateObject("Word.Application")
    Set WordDoc = WordApp.Documents.Open(NDF, ReadOnly:=False)

A noter : on prévoit dès le début de sauvegarder le document avec un nom comportant ici le contenu de la cellule A1 (un nom de client par exemple) pour ne pas écraser le modèle.

Puis il convient d'écrire les données :
* pour écrire à partir du signet "SIGNET_A CREER_DANS_DOCUMENT_WORD" (ici le contenu de la cellule A2 :

    With WordApp
        .Visible = False
        .Selection.Goto What:=wdGoToBookmark, Name:="SIGNET_A CREER_DANS_DOCUMENT_WORD"
        .Selection.TypeText Text:= Sheets("Feuil1").Range("A2").Value

* pour écrire dans le tableau 1 ligne 1, colonne 2 (ici le contenu de la cellule A3) :

        With WordDoc.Tables(1)
            .Cell(1, 2).Range.InsertAfter Sheets("Feuil1").Range("A3").Value
        End With

Ne pas oublier de sauvegarder le document sous le nom défini précédemment :

    WordDoc.Application.ActiveDocument.SaveAs NDF2

Enfin, il convient de fermer le tout proprement et de libérer la mémoire en mettant les variables à zéro :

    WordApp.Application.Quit
    Set WordDoc = Nothing
    Set WordApp = Nothing

Ce qui donne au global :

Sub Vers_Word()
Dim NDF As String, NDF2 As String
Dim WordApp As Word.Application
Dim WordDoc As Word.Document

    NDF = ActiveWorkbook.Path & "\ModèleDocument.doc"
    NDF2 = ActiveWorkbook.Path & "\Document" & Sheets("Feuil1").Range("A1").text & ".doc"
    
    On Error Resume Next
    Set WordApp = CreateObject("Word.Application")
    Set WordDoc = WordApp.Documents.Open(NDF, ReadOnly:=False)
    
    With WordApp
        .Visible = False
        .Selection.Goto What:=wdGoToBookmark, Name:="SIGNET_A CREER_DANS_DOCUMENT_WORD"
        .Selection.TypeText Text:= Sheets("Feuil1").Range("A2").Value

        With WordDoc.Tables(1)
            .Cell(1, 2).Range.InsertAfter Sheets("Feuil1").Range("A3").Value
        End With
    End With
    
    WordDoc.Application.ActiveDocument.SaveAs NDF2
    WordApp.Application.Quit
    Set WordDoc = Nothing
    Set WordApp = Nothing

End Sub

La référence MS Word machin est activéé bien sûr!

Pour adapter à partir d'un Usf, il suffit de remplacer les contenus des cellules par les valeurs des champs de l'Usf (macro dans le code de l'Usf également) et le tour est joué!

Bon ouikend