Somme de valeurs en fonction de la date

[Jx7]

Bonjour à toutes et à tous,

Est-ce que l'un de vous aurait une idée sur le problème suivant?

(je me debrouille sous Excel et j'ai déjà touché au VBA mais j'ai des besoins ponctuels donc je pratique pas régulièrement)

Dans une "Feuille 1" j'ai une liste de dates aléatoires mais chronologiques avec une valeur pour chacune de ses dates. exemple:

04/01/2006 420
20/01/2006 122
01/02/2006 780
25/03/2006 300
26/03/2006 150
30/03/2006 466
10/04/2006 561
etc...

J'aimerais récupérer la somme des valeurs pour chaque mois. Ce qui donnerais dans cet exemple:
01/2006 542
02/2006 780
03/2006 916
04/2006 561
etc...

Voilà :s Ca sent le VBA et de monstrueuses macro j'imagine... Mais à tout hasard, si quelqu'un savait comment faire ça sous Excel, ce serait + simple et parfait pour moi

Merci par avance.

++

[Tibo]

Salut Jx,

Essaye avec la fonction SOMMEPROD :

Tes données en colonne A et B

en D1 (par exemple) : janvier 2006
en E1 : SOMMEPROD((MOIS(A1:A7)=MOIS(D1))*B1:B7)

@+

[Jx7]

Trop fort!!! ^^

et une réponse super rapide en +

J'ai mis un moment à comprendre mais j'ai compris

Par contre avec cette formule ca prend que le mois donc quand je vais arriver à 2007 il va m'additioner les valeurs de janvier 2006 avec celles de janvier 2007 :s

est ce qu'on peut ajouter la sélection de l'année dans ta formule magique? J'essaie mais en vain...

Merci en tout cas c'est tip top

++

[Tibo]

re,

Pour faire le distingo en tenant compte de l'année :

en E1 : =SOMMEPROD((ANNEE(A1:A7)=ANNEE(D1))*(MOIS(A1:A7)=M OIS(D1))*B1:B7)

Voilou

Bonne soirée

@+

[Jx7]

ARGH! J'avais presque trouvé!

En tout cas merci pour ton aide ;-)

tip top!!!!

[Foufoudora]

Salut j'ai le même problème mais plusieurs lignes de saisies par jour.
j'aimerai avir la SOMMEPROD de chaque jour.

Ex:
01/01/2006 100
01/01/2006 250
03/01/2006 200
01/06/2006 20
01/06/2006 30
01/06/2006 40
etc

Merci d'avance

[Monique]

Bonjour,

Dates sans doublons par Grande.Valeur()
et SommeProd ou Somme.Si

[Foufoudora]

Meci beaucoup tu es un amour

peux-tu voir mon message de Intégration SOMMEPROD MACRO sur le forum

Merci d'avance

[Monique]

Re,

J'ai vu ce message, oui.
Mais je n'y connais rien en macro

[Foufoudora]

comme même un grand merci

Foufoudora

[Jx7]

Envoyé par Tibo

re,

Pour faire le distingo en tenant compte de l'année :

en E1 : =SOMMEPROD((ANNEE(A1:A7)=ANNEE(D1))*(MOIS(A1:A7)=M OIS(D1))*B1:B7)

Voilou

Bonne soirée

@+

Je reviens à l'assaut avec un nouveau problème lié à cette formule:

colonne A: les dates
colonne B: les chiffres
colonne D: les mois (01/2006, 02/2006, 03/2006, etc...)
colonne E: la formule

Quand je tape les chiffres à la main dans la colonne B, ça marche impec. mais quand ces chiffres sont eux mêmes issus d'une formule, ma formule de la colonne E déconne et m'affiche #VALEUR!

some idea?

edit: je viens de m'apercevoir que ça n'arrive que lorsqu'au moins une case de la colonne B est vide (c'est toujours le résultat d'une formule)

[Monique]

Bonjour,

Fais un essai en remplaçant le dernier * par un point-virgule :
=SOMMEPROD((ANNEE(A$1:A$20)=ANNEE(D1))*(MOIS(A$1:A $20)=MOIS(D1));B$1:B$20)

[Jx7]

Envoyé par Monique

Bonjour,

Fais un essai en remplaçant le dernier * par un point-virgule :
=SOMMEPROD((ANNEE(A$1:A$20)=ANNEE(D1))*(MOIS(A$1:A $20)=MOIS(D1));B$1:B$20)

PARFAIT! merci ^^

par contre j'ai un peu de mal à comprendre le déroulement du calcul et ça m'enerve...

++

[Monique]

Re,

SommeProd fait la somme des produits, ligne par ligne

Tu prends les valeurs de ton 1er message, en A1:A7 et B1:B7
=SOMMEPROD((ANNEE(A$1:A$7)=ANNEE(D1))*(MOIS(A$1:A$7)=MOIS(D1));B$1:B$7)

Dans la barre de formule, tu sélectionnes la partie en bleu et tu appuies sur F9, ça donne :
=SOMMEPROD(({VRAI;VRAI;VRAI;VRAI;VRAI;VRAI;VRAI})* (MOIS(A$1:A$7)=MOIS(D1));B$1:B$7)

Idem avec la partie en bleu, ça donne :
=SOMMEPROD(({VRAI;VRAI;VRAI;VRAI;VRAI;VRAI;VRAI})* ({VRAI;VRAI;FAUX;FAUX;FAUX;FAUX;FAUX});B$1:B$7)

Idem avec la fin, ça donne :
=SOMMEPROD(({VRAI;VRAI;VRAI;VRAI;VRAI;VRAI;VRAI})*({VRAI;VRAI ;FAUX;FAUX;FAUX;FAUX;FAUX});{420;122;780;300;150;466;561})

Idem avec le nouveau début, ça donne :
=SOMMEPROD({1;1;0;0;0;0;0};{420;122;780;300;150;46 6;561})

VRAI équivaut à 1 et FAUX à 0
VRAI*VRAI = 1
VRAI*FAUX = 0
FAUX*FAUX = 0

=SOMMEPROD({1;1;0;0;0;0;0};{420;122;780;300;150;46 6;561})
équivaut à :
=SOMME(1*420;1*122;0*780;0*300;0*150;0*466;0*561)

Si on ne veut compter que le nombre de mois répondant au critère :
=SOMMEPROD((MOIS($A$1:$A$7)=MOIS(D1))*1)
=SOMMEPROD(({VRAI;VRAI;FAUX;FAUX;FAUX;FAUX;FAUX})* 1)
=SOMME(({1;1;0;0;0;0;0})*1)

[nat54]

WOW merci pour cette explication , j'ai ENFIN compris comment le SOMMEPROD fonctionne !