Coller avec Shapes.Paste

Re-bonjour tout le monde,

J'ai une macro Excel VB qui copie une graphique Excel dans un document Powerpoint :

'On active, selectionne et copie le graphique 1 de Excel : Répartition des demandes par transactions
ActiveSheet.ChartObjects("Graphique 1").Activate
ActiveChart.ChartArea.Select
ActiveChart.ChartArea.Copy
'On le colle dans la diapositive N°3 de la présentation
Pres.Slides(3).Shapes.Paste

Comment je sais sous quel nom d'objet ce graphique va être enregistré dans le document ppt?

Ou mieux, par quel moyen je peux coller mon graphique dans le ppt en lui indiquant un nom d'objet que j'aurais choisi?

Merci tout le monde

Toujours sur le même sujet, quand je colle mon graphique avec Shapes.Paste, ça me le colle n'importe où.
Comment je peux faire pour lui dire la position à laquelle je veux qu'il soit collé dans ma diapo?

Je galère vraiment sur ce sujet, sûrement par manque de connaissance, car ça ne doit pas être très compliqué.

Merci beaucoup à ceusses qui pourront m'aider.

Re-bonjour,

Je retente ma chance.
Personne n'a une petite idée?, un petit mot magique du genre :

Pres.Slides(3).Shapes.Paste, nom objet = "tartenpion", position=....


pour que mon graphique, une fois collé dans le doc ppt, soit à la bonne position dans la diapo, et que l'objet s'appelle "Tartenpion".

merci

bonjour Lyann


j'espere que cet exemple répondra à ta demande


Sub insertionGraphiqueDansPowerPoint()
'necessite d'activer la reference Microsoft Powerpoint Object Library
Dim PPT As PowerPoint.Application
Dim PptDoc As PowerPoint.Presentation
Dim NbShpe As Byte

Set PPT = CreateObject("Powerpoint.Application") 'creation session PowerPoint
PPT.Visible = True
Set PptDoc = PPT.Presentations.Open("C:\monfichier.ppt") 'ouverture fichier ppt

ActiveSheet.ChartObjects("Graphique 1").Copy 'copie du "Graphique 1" de la feuille active
PptDoc.Slides(3).Shapes.Paste 'collage dans le Slide3 du document Power Point

'compte le nombre de shapes dans le 3eme slide
'le dernier objet inséré correspond à l'index le plus élevé
NbShpe = PptDoc.Slides(3).Shapes.Count

With PptDoc.Slides(3).Shapes(NbShpe)
.Name = "monGraph" 'personnaliser le nom de l'image insérée
.Left = 150 'position horizontale dans le slide
.Top = 100 'position verticale dans le slide
.Height = 300 'hauteur image
.Width = 400 'largeur image
End With

'PptDoc.Save 'sauvegarder les modifications
'PptDoc.Close 'fermer le document ppt
'PPT.Quit 'fermer l'application powerPoint
End Sub


bonne soirée
MichelXld