Des champions VB/Word? (dsl, je m'egare du sujet)

Bonjour a tous,
Certains me diront que ce n'est pas le site approprié, j'en suis tout a fait conscient. Mais je galere pas mal, et ici les reponses sont souvent bonnes et claires.
De plus entre Excel/VBA et Word/VB y a un miniscule petit pas, j'ecris donc en esperant qu'un ou une soit en mesure de le franchir.

Mon probleme :
Je pilote word a partir d'une application VB.
J'insere une image dans mon document, mais comment placer cette image devant le texte? A la main faut faire click droit sur l'image/Propriétés/Habillage et choisir "devant le texte".
Ne connaissant pas le code j'ai voulu créer une nouvelle macro sous word et faire ca a la main, pour recuperer le code généré, mais impossible, je peux pas jouer avec le style d'habillage pendant l'enregistrement de la macro (pour info : VB6 - Office XP)
Merci a celui/celle qui aura la réponse, merci aussi a ceux qui auront cherché sans resultats .

José

bonjour José

La procédure Excel ci dessous permet d'ouvrir un document Word existant et d'y insérer une image , de la redimensionner , de la positionner à un endroit précis dans le document et devant le texte .


Sub InsertImageDansDocWord()
'activer la reference Microsoft Word 10.0 Object Library
Dim WrdApp As Word.Application
Dim WrdDoc As Word.Document
Dim Fichier As String

On Error Resume Next
Fichier = "C:\Documents and Settings\michel\dossier\general\excel\testpilotage Word.doc"

Set WrdApp = CreateObject("Word.Application")
WrdApp.Visible = True
Set WrdDoc = WrdApp.Documents.Open(Fichier) 'ouvrir le document Word

WrdDoc.InlineShapes.AddPicture Filename:= _
"C:\Documents and Settings\michel\Mes documents\Mes images\PICT1037.JPG" 'adapter le chemin de l'image à insérer
On Error GoTo 0

With WrdDoc.InlineShapes(1) 'adapter l'index si d'autres images existantes dans le document
.Height = 190.75 'changement dimension image insérée : hauteur
.Width = 254# 'largeur
.ConvertToShape
End With

With WrdDoc.Shapes(1)
.Top = 200 'position verticale de l'image dans le document
.Left = 150 'position horizontale de l'image dans le document
.ZOrder msoBringInFrontOfText 'image au premier plan devant le texte
'.ZOrder msoSendBehindText 'option pour image en arriere plan derriere le texte
End With

'WrdDoc.Close 'fermer le document Word
'WrdApp.Quit 'fermer l'application Word

End Sub


testé avec winXP et Excel2002
je n'ai aucune idée si cela marchera aussi avec VB6 . j'espere que cela pourra tout de meme t'aider


bonne soiree
MichelXld