Trouvez date

Je cherche à calculer une date d'embauche dans excel:

Pour une date donnée, j'ai un employé qu'on lui reconnait 8 ans et 54 jours d'ancienneté, je veux savoir sa date d'entrée en fonction.

Comment faire dans excel: date d'aujourd'hui - 8 ans et 54 jours ??

Bien entendu, je dois tenir compte des années de 366 ou 365 jours.

Merci à l'avance

Salut,

Teste ça

Cordialement

Le rital


Date d'entrée en fonction = mardi 26/09/1995

La fonction DATEDIF

DATEDIF permet de calculer la différence entre deux dates en années, mois et jours.

Syntaxe : =DATEDIF(Date1;Date2;Intervalle)

Cette fonction renvoie la différence entre Date1 et Date2 (Date2 >= Date1) selon l'argument Intervalle, qui peut prendre les valeurs suivantes :

"y" : différence en années
"m" : différence en mois
"d" : différence en jours
"ym" : différence en mois, une fois les années soustraites
"yd" : différence en jours, une fois les années soustraites
"md" : différence en jours, une fois les années et les mois soustraits

Exemple :

=DATEDIF("5/4/1990";"15/8/99";Intervalle) renvoie les valeurs suivantes selon la valeur de l'argument Intervalle :

"y" : 9 (ans)
"m" : 112 (mois)
"d" : 3419 (jours)
"ym" : 4 (mois restants, une fois les 9 ans soustraits)
"yd" : 132 (jours restants, une fois les 9 ans soustraits)
"md" : 10 (jours restants, une fois les 112 mois soustraits)

La fonction DATEDIF peut être en particulier utilisée pour calculer des âges. Par exemple, si la cellule A1 contient une date de naissance et la cellule B1 la date du jour :

- Age en années simples :

=DATEDIF(A1;B1;"y")&SI(DATEDIF(A1;B1;"y")>1;" ans";" an")

- Age en années et mois :

=DATEDIF(A1;B1;"y")&SI(DATEDIF(A1;B1;"y")>1;" ans, ";" an, ")
&DATEDIF(A1;B1;"ym")&" mois"

- Age en années, mois et jours :

=DATEDIF(A1;B1;"y")&SI(DATEDIF(A1;B1;"y")>1;" ans, ";" an, ")&DATEDIF(A1;B1;"ym")
&" mois, "&DATEDIF(A1;B1;"md")&SI(DATEDIF(A1;B1;"md")>1 ;" jours";" jour")

Bonsoir à tous

Le Rital, j'ai compris que Michel voulait obtenir la date d'entrée à partir de l'écart entre cette date d'arrivée et aujourd'hui, donc l'inverse de toi.

Si c'est le cas, voici une formule:
=DATE(ANNEE(AUJOURDHUI())-8;MOIS(AUJOURDHUI());JOUR(AUJOURDHUI()))-54

Ou bien, si les valeurs d'années et jours d'ancienneté se trouvent dans des cellules, par exemple A1 et A2, alors la formule devient:
=DATE(ANNEE(AUJOURDHUI())-A1;MOIS(AUJOURDHUI());JOUR(AUJOURDHUI()))-A2

La cellule ou se trouve la formule doit être en format date (mais je crois que cela se fait automatiquement)

Bonne soirée.
Laurent.